0683dde5d3
cargo-xwin drives the Windows MSVC cross-compile via clang-cl, under which CMake sets MSVC=1 — causing libopus 1.3.1's `if(NOT MSVC)` guards to skip the per-file `-msse4.1` / `-mssse3` COMPILE_FLAGS that its x86 SIMD source files need. Clang-cl (unlike real cl.exe) still honors Clang's target-feature system, so those files then fail to compile with "always_inline function '_mm_cvtepi16_epi32' requires target feature 'sse4.1'" errors across silk/NSQ_sse4_1.c, NSQ_del_dec_sse4_1.c, and VQ_WMat_EC_sse4_1.c. Earlier attempts to fix this downstream (cargo-xwin toolchain file, override.cmake CMAKE_C_COMPILE_OBJECT <FLAGS> replace, CFLAGS env vars) all failed because cargo-xwin rewrites override.cmake from scratch on every `cargo xwin build` invocation and cmake-rs's -DCMAKE_C_FLAGS= assembly happens before toolchain FORCE sets propagate. Fixing it upstream at the source: vendor audiopus_sys 0.2.2 into vendor/audiopus_sys, patch its bundled opus/CMakeLists.txt to introduce an MSVC_CL var (true only when CMAKE_C_COMPILER_ID == "MSVC", i.e. real cl.exe), and flip the eight `if(NOT MSVC)` SIMD guards to `if(NOT MSVC_CL)`. Clang-cl then gets the GCC-style per-file flags and the SSE4.1 sources build cleanly. Also flip the `if(MSVC)` global /arch block at line 445 to `if(MSVC_CL)` so only cl.exe applies /arch:AVX and clang-cl relies purely on per-file flags (no global/per-file mixing). Wire via [patch.crates-io] in the workspace root Cargo.toml; the patch is resolved relative to the workspace root as `vendor/audiopus_sys`. Upstream context: xiph/opus#256, xiph/opus PR #257 (both stale). Co-Authored-By: Claude Opus 4.6 (1M context) <noreply@anthropic.com>
105 lines
2.9 KiB
CMake
105 lines
2.9 KiB
CMake
if(__opus_config)
|
|
return()
|
|
endif()
|
|
set(__opus_config INCLUDED)
|
|
|
|
include(OpusFunctions)
|
|
|
|
configure_file(cmake/config.h.cmake.in config.h @ONLY)
|
|
add_definitions(-DHAVE_CONFIG_H)
|
|
|
|
set_property(GLOBAL PROPERTY USE_FOLDERS ON)
|
|
set_property(GLOBAL PROPERTY C_STANDARD 99)
|
|
|
|
if(MSVC)
|
|
add_definitions(-D_CRT_SECURE_NO_WARNINGS)
|
|
endif()
|
|
|
|
include(CheckLibraryExists)
|
|
check_library_exists(m floor "" HAVE_LIBM)
|
|
if(HAVE_LIBM)
|
|
list(APPEND OPUS_REQUIRED_LIBRARIES m)
|
|
endif()
|
|
|
|
include(CFeatureCheck)
|
|
c_feature_check(VLA)
|
|
|
|
include(CheckIncludeFile)
|
|
check_include_file(alloca.h HAVE_ALLOCA_H)
|
|
|
|
include(CheckSymbolExists)
|
|
if(HAVE_ALLOCA_H)
|
|
add_definitions(-DHAVE_ALLOCA_H)
|
|
check_symbol_exists(alloca "alloca.h" USE_ALLOCA_SUPPORTED)
|
|
else()
|
|
check_symbol_exists(alloca "stdlib.h;malloc.h" USE_ALLOCA_SUPPORTED)
|
|
endif()
|
|
|
|
include(CheckFunctionExists)
|
|
check_function_exists(lrintf HAVE_LRINTF)
|
|
check_function_exists(lrint HAVE_LRINT)
|
|
|
|
if(CMAKE_SYSTEM_PROCESSOR MATCHES "(i[0-9]86|x86|X86|amd64|AMD64|x86_64)")
|
|
if(CMAKE_SIZEOF_VOID_P EQUAL 8)
|
|
set(OPUS_CPU_X64 1)
|
|
else()
|
|
set(OPUS_CPU_X86 1)
|
|
endif()
|
|
elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "(arm|aarch64)")
|
|
set(OPUS_CPU_ARM 1)
|
|
endif()
|
|
|
|
if(NOT OPUS_DISABLE_INTRINSICS)
|
|
opus_supports_cpu_detection(RUNTIME_CPU_CAPABILITY_DETECTION)
|
|
endif()
|
|
|
|
if(OPUS_CPU_X86 OR OPUS_CPU_X64 AND NOT OPUS_DISABLE_INTRINSICS)
|
|
opus_detect_sse(COMPILER_SUPPORT_SIMD)
|
|
elseif(OPUS_CPU_ARM AND NOT OPUS_DISABLE_INTRINSICS)
|
|
opus_detect_neon(COMPILER_SUPPORT_NEON)
|
|
if(COMPILER_SUPPORT_NEON)
|
|
option(OPUS_USE_NEON "Option to enable NEON" ON)
|
|
option(OPUS_MAY_HAVE_NEON "Does runtime check for neon support" ON)
|
|
option(OPUS_PRESUME_NEON "Assume target CPU has NEON support" OFF)
|
|
if(CMAKE_SYSTEM_PROCESSOR MATCHES "aarch64")
|
|
set(OPUS_PRESUME_NEON ON)
|
|
elseif(CMAKE_SYSTEM_NAME MATCHES "iOS")
|
|
set(OPUS_PRESUME_NEON ON)
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
if(MSVC)
|
|
check_flag(FAST_MATH /fp:fast)
|
|
check_flag(STACK_PROTECTOR /GS)
|
|
check_flag(STACK_PROTECTOR_DISABLED /GS-)
|
|
else()
|
|
check_flag(FAST_MATH -ffast-math)
|
|
check_flag(STACK_PROTECTOR -fstack-protector-strong)
|
|
check_flag(HIDDEN_VISIBILITY -fvisibility=hidden)
|
|
set(FORTIFY_SOURCE_SUPPORTED 1)
|
|
endif()
|
|
|
|
if(MINGW)
|
|
# For MINGW we need to link ssp lib for security features such as
|
|
# stack protector and fortify_sources
|
|
check_library_exists(ssp __stack_chk_fail "" HAVE_LIBSSP)
|
|
if(NOT HAVE_LIBSSP)
|
|
message(WARNING "Could not find libssp in MinGW, disabling STACK_PROTECTOR and FORTIFY_SOURCE")
|
|
set(STACK_PROTECTOR_SUPPORTED 0)
|
|
set(FORTIFY_SOURCE_SUPPORTED 0)
|
|
endif()
|
|
endif()
|
|
|
|
if(NOT MSVC)
|
|
set(WARNING_LIST -Wall -W -Wstrict-prototypes -Wextra -Wcast-align -Wnested-externs -Wshadow)
|
|
include(CheckCCompilerFlag)
|
|
foreach(WARNING_FLAG ${WARNING_LIST})
|
|
string(REPLACE - "" WARNING_VAR ${WARNING_FLAG})
|
|
check_c_compiler_flag(${WARNING_FLAG} ${WARNING_VAR}_SUPPORTED)
|
|
if(${WARNING_VAR}_SUPPORTED)
|
|
add_compile_options(${WARNING_FLAG})
|
|
endif()
|
|
endforeach()
|
|
endif()
|